home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 17 / CU Amiga Magazine's Super CD-ROM 17 (1997)(EMAP Images)(GB)[!][issue 1997-12].iso / CUCD / Programming / DiceSource / src / alib / csup / timer_support / TimeDelay.asm < prev    next >
Assembly Source File  |  1995-12-24  |  6KB  |  254 lines
  1. *************************************************************************
  2. *                                    *
  3. *    Copyright (C) 1989, Commodore Amiga Inc.  All rights reserved.    *
  4. *                                    *
  5. *************************************************************************
  6.  
  7.  
  8. *************************************************************************
  9. *
  10. * TimeDelay.asm
  11. *
  12. * Source Control
  13. * ------ -------
  14. * 
  15. * $Id: TimeDelay.asm,v 30.0 1994/06/10 18:10:51 dice Exp $
  16. *
  17. * $Locker:  $
  18. *
  19. *************************************************************************
  20.  
  21.     SECTION    timer
  22.  
  23. *------ Included Files -----------------------------------------------
  24.  
  25.     INCLUDE    'exec/types.i'
  26. ;    INCLUDE    'exec/interrupts.i'
  27.  
  28.     INCLUDE    'devices/timer.i'
  29.  
  30. *------ Imported Names -----------------------------------------------
  31.  
  32. *------ Tables -------------------------------------------------------
  33.  
  34. *------ Defines ------------------------------------------------------
  35.  
  36. CALLSYS    MACRO
  37.     JSR    _LVO\1(A6)
  38.     ENDM
  39.  
  40. XSYS    MACRO
  41.     XREF    _LVO\1
  42.     ENDM
  43.  
  44.  
  45. *------ Functions ----------------------------------------------------
  46.  
  47.  
  48. *------ System Library Functions -------------------------------------
  49.  
  50.     XSYS    AllocSignal
  51.     XSYS    FreeSignal
  52.     XSYS    DoIO
  53.     XSYS    FindTask
  54.     XSYS    OpenDevice
  55.     XSYS    CloseDevice
  56.  
  57. *------ Exported Names -----------------------------------------------
  58.  
  59. *------ Functions ----------------------------------------------------
  60.  
  61.     XDEF    TimeDelay
  62.     XDEF    _TimeDelay
  63.  
  64. *------ Data ---------------------------------------------------------
  65.  
  66. *------ Local Definitions --------------------------------------------
  67.  
  68. timerName:    TIMERNAME
  69.  
  70.  
  71.  
  72.  
  73. ******* amiga.lib/TimeDelay ******************************************
  74. *
  75. *   NAME
  76. *    TimeDelay -- Return after a period of time has elapsed.
  77. *
  78. *   SYNOPSIS
  79. *    Error = TimeDelay( Unit, Seconds, MicroSeconds )
  80. *    D0                 D0    D1       D2
  81. *
  82. *    LONG TimeDelay( LONG, ULONG, ULONG );
  83. *
  84. *   FUNCTION
  85. *    Waits for the period of time specified before returning to the
  86. *    the caller.
  87. *
  88. *   INPUTS
  89. *    Unit -- timer.device unit to open for this command.
  90. *    Seconds -- The seconds field of a timerequest is filled with
  91. *        this value. Check the documentation for what a particular
  92. *        timer.device unit expects there.
  93. *    MicroSeconds -- The microseconds field of a timerequest is
  94. *        filled with this value. Check the documentation for what
  95. *        a particular timer.device units expects there.
  96. *
  97. *   RESULTS
  98. *    Error -- will be zero if all went well; otherwise, non-zero.
  99. *
  100. *   NOTES
  101. *    Two likely reasons for failures are invalid unit numbers or
  102. *    no more free signal bits for this task.
  103. *
  104. *    While this function first appears in V37 amiga.lib, it works
  105. *    on Kickstart V33 and higher.
  106. *
  107. *   SEE ALSO
  108. *    timer.device/TR_ADDREQUEST,
  109. *    timer.device/TR_WAITUNTIL,
  110. *    timer.device/WaitUnitl()
  111. *
  112. *   BUGS
  113. *
  114. **********************************************************************
  115. *
  116. *   IMPLEMENTATION NOTES
  117. *
  118. *
  119. *   REGISTER USAGE
  120. *
  121.  
  122. _TimeDelay:
  123.         move.l    d2,-(sp)
  124.         move.l    8(sp),d0        ; timer unit
  125.         move.l    12(sp),d1        ; seconds
  126.         move.l    16(sp),d2        ; useconds
  127.         bsr.s    TimeDelay
  128.         move.l    (sp)+,d2
  129.         rts
  130.  
  131. TimeDelay:
  132.         subq.l    #TV_SIZE,sp        ; make a timeval
  133.         move.l    sp,a0
  134.         movem.l    d1/d2,(a0)        ; set timeval
  135.         move.l    #TR_ADDREQUEST,d1    ; set the device command
  136.         bsr.s    DoTimer            ; gotoit
  137.         addq.l    #TV_SIZE,sp
  138.         rts
  139.  
  140.  
  141. *****i* timer.device/internal/DoTimer ********************************
  142. *
  143. *   NAME
  144. *    DoTimer -- "DoIO" a timer.device command. (V36)
  145. *
  146. *   SYNOPSIS
  147. *    Error = DoTimer( TimeVal, Unit, Command )
  148. *    D0               A0       D0    D1
  149. *
  150. *    LONG DoTimer( struct timeval *, LONG, WORD );
  151. *
  152. *   FUNCTION
  153. *    Create a timerequest and reply port then perform the
  154. *    device command via DoIO.
  155. *
  156. *   INPUTS
  157. *    TimeVal -- pointer to a timeval structure. Contents copied
  158. *        into IORequest before DoIO.
  159. *    Unit -- timer.device unit to open for this command.
  160. *    Command -- command to perform.
  161. *
  162. *   RESULTS
  163. *    TimeVal -- filled from timeval structure of IORequest after
  164. *        command completes.
  165. *    Error -- will be zero if all went well; otherwise, non-zero.
  166. *
  167. *   NOTES
  168. *
  169. *   SEE ALSO
  170. *
  171. *   BUGS
  172. *
  173. **********************************************************************
  174. *
  175. *   IMPLEMENTATION NOTES
  176. *
  177. *
  178. *   REGISTER USAGE
  179. *
  180.  
  181. DoTimer:
  182.         movem.l    d2-d3/a2-a4/a6,-(sp)
  183.         move.l    4,a6            ; find execbase
  184.         move.l    a0,a4            ; timeval
  185.         move.l    d0,d2            ; unit
  186.         move.l    d1,d3            ; command
  187.  
  188.         lea    -MP_SIZE-IOTV_SIZE(sp),sp
  189.         movea.l    sp,a3            ; IORequest
  190.         lea    IOTV_SIZE(a3),a2    ; reply port
  191.  
  192.         move.b    #NT_MSGPORT,LN_TYPE(a2)    ; set up the node type
  193.         clr.b    LN_PRI(a2)
  194.         clr.l    LN_NAME(a2)        ; no name
  195.         clr.b    MP_FLAGS(a2)
  196.  
  197.         moveq.l    #-1,d0
  198.         CALLSYS    AllocSignal        ; get port signal bit
  199.         cmp.b    #-1,d0
  200.         beq    DTError1
  201.         move.b    d0,MP_SIGBIT(a2)
  202.  
  203.         suba.l    a1,a1            ; find this task
  204.         CALLSYS    FindTask
  205.         move.l    d0,MP_SIGTASK(a2)    ; and fill in this task
  206.         lea    MP_MSGLIST(a2),a0
  207.         NEWLIST    a0            ; initialise message port
  208.  
  209.         lea    timerName,A0
  210.         movea.l    a3,a1            ; this IORequest
  211.         move.l    d2,d0            ; this unit
  212.         moveq.l    #0,d1            ; no special flags
  213.         CALLSYS    OpenDevice
  214.         tst.l    d0            ; any errors ?
  215.         bne.s    DTError2        ; yep
  216.  
  217.         move.l    a2,MN_REPLYPORT(a3)    ; replies go to this port
  218.         
  219.         movea.l    a3,a1
  220.         move.w    d3,IO_COMMAND(a1)    ; this command
  221.  
  222.         move.l    TV_SECS(a4),IOTV_TIME+TV_SECS(a1)
  223.         move.l    TV_MICRO(a4),IOTV_TIME+TV_MICRO(a1)
  224.  
  225.         CALLSYS    DoIO            ; doit
  226.  
  227.         move.l    IOTV_TIME+TV_SECS(a3),TV_SECS(a4)
  228.         move.l    IOTV_TIME+TV_MICRO(a3),TV_MICRO(a4)
  229.  
  230.         movea.l    a3,a1
  231.         CALLSYS    CloseDevice        ; close the device
  232.  
  233.         moveq.l    #0,d0
  234.         move.b    MP_SIGBIT(a2),d0
  235.         CALLSYS    FreeSignal        ; free port signal
  236.  
  237. DTCleanup:
  238.         lea.l    IOTV_SIZE+MP_SIZE(sp),sp    ; clean up stack
  239.         movem.l    (sp)+,d2-d3/a2-a4/a6
  240.         rts
  241.  
  242. DTError2:
  243.         moveq.l    #0,d0
  244.         move.b    MP_SIGBIT(a2),d0
  245.         CALLSYS    FreeSignal        ; free port signal
  246.  
  247. DTError1:
  248.         moveq.l    #-1,d0
  249.         bra.s    DTCleanup
  250.  
  251.  
  252.     END
  253.  
  254.